TIEBitmap.JoinBitmaps

Declaration

function JoinBitmaps(Source1, Source2: TIEBitmap; JoinVertically: Boolean; BGColor: TColor = clWhite; StripOverlap: Boolean = False; MinEquality: Double = 0.99;  Exhaustive: Boolean = False; Coverage: Double = 1.0): Integer;

Description

Replaces the content with two source images drawn side-by-side (or above and below if JoinVertically=True).
Both bitmaps must be ie24RGB.
If StripOverlap = True, then the result is the number of rows/colums that were cropped (if the result is 0 then no overlap could be found).
   

Note:
◼You may specify the current bitmap for Source1 or Source2
◼if StripOverlap = True it looks for overlap at a maximum of 50% of the width/height of the smallest image
◼If attached to a TImageEnView, it will automatically call Update
◼Also see TIEVisionStitcher which allows joining of multiple images with overlapped content

TIEBitmap Assignment and Drawing Methods

TBitmap Methods

TCanvas Methods

Comparison

// Joining two bitmaps that are 300px wide with some overlapping content

   


// METHOD 1 - JOIN ONLY

// Join two images horizontally and display them (without checking for overlapping content)
bmpL := TIEBitmap.Create();
bmpR := TIEBitmap.Create();
bmpL.LoadFromFile( 'D:\JoinBitmap_Left.png' );
bmpR.LoadFromFile( 'D:\JoinBitmap_Right.png' );
ImageEnView1.IEBitmap.JoinBitmaps( bmpL, bmpR, False, clNone );
bmpL.Free;
bmpR.Free;

// Result is 600px wide - Overlap remains




// METHOD 2 - NON-EXHAUSTIVE CHECKING FOR OVERLAP

// Join two images horizontally and display them (performing a non-exhaustive search for overlapping content)
bmpL := TIEBitmap.Create();
bmpR := TIEBitmap.Create();
bmpL.LoadFromFile( 'D:\JoinBitmap_Left.png' );
bmpR.LoadFromFile( 'D:\JoinBitmap_Right.png' );
ImageEnView1.IEBitmap.JoinBitmaps( bmpL, bmpR, False, clNone, True, 0.99 );
bmpL.Free;
bmpR.Free;

// Result is 477px wide - Small amount of overlap remains




// METHOD 3 - EXHAUSTIVE CHECKING FOR OVERLAP

// Join two images horizontally and display them (performing an exhaustive search for overlapping content)
bmpL := TIEBitmap.Create();
bmpR := TIEBitmap.Create();
bmpL.LoadFromFile( 'D:\JoinBitmap_Left.png' );
bmpR.LoadFromFile( 'D:\JoinBitmap_Right.png' );
ImageEnView1.IEBitmap.JoinBitmaps( bmpL, bmpR, False, clNone, True, 0.8, True );
bmpL.Free;
bmpR.Free;

// Result is 473px wide - Overlap is correctly removed

Examples

// Draw an image on the right of the current image (blank space will be transparent)
bmp := TIEBitmap.Create();
bmp.LoadFromFile( 'D:\image2.png' );
ImageEnView1.IEBitmap.JoinBitmaps( nil, bmp, False, clNone );
bmp.Free;


// Create a PDF document with two stacked landscape images
bmp1 := TIEBitmap.Create();
bmp2 := TIEBitmap.Create();
destBmp := TIEBitmap.Create();

bmp1.LoadFromFile( 'D:\im1.jpg' );
bmp2.LoadFromFile( 'D:\im2.jpg' );

destBmp.JoinBitmaps( bmp1, bmp2, True, clWhite );

destBmp.RemoveAlphaChannel( True );            // Discard any alpha channel if not needed to reduce file size
destBmp.ParamsEnabled := True;
destBmp.Params.PDF_PaperSize   := iepA4;
destBmp.Params.PDF_Compression := ioPDF_JPEG;
destBmp.Params.JPEG_Quality    := 90;
IEGlobalSettings().PDFEngine := ieenNative;    // For compression support
destBmp.SaveToFile('D:\out.pdf');

bmp1.Free();
bmp2.Free();
destBmp.Free();


// Duplicate the current bitmap vertically
bmp.JoinBitmaps( bmp, bmp, True  );


// Join two images removing any part of the image that is the same at the joining edge
// Exact matches only. Don't use exact matches for lossy formats like JPEG
ImageEnView3.IEBitmap.JoinBitmaps( ImageEnView1.IEBitmap, ImageEnView2.IEBitmap, False, clWhite, True, 1.0 );


// Or perform an exhaustive search which gives the best result, but is much slower (because it checks every possibility)
// (You can specify a low value for MinEquality if Exhaustive is used)
ImageEnView3.IEBitmap.JoinBitmaps( ImageEnView1.IEBitmap, ImageEnView2.IEBitmap, False, clWhite, True, 0.5, True );


// Quick joining of two images removing any part of the image that is the same at the joining edge
// This method only checks every 100th row so overlap detection may not be as accurate, but it is much faster
ImageEnView3.IEBitmap.JoinBitmaps( ImageEnView1.IEBitmap, ImageEnView2.IEBitmap, False, clWhite, True, 0.98, False, 0.01 );


// Horizontally join 5 images that have overlapping joining edges
bmpIn  := TIEBitmap.Create();
bmpOut := TIEBitmap.Create();

for i := 1 to 5 do
begin
  bmpIn.LoadFromFile( 'D:\Join' + i.ToString + '.jpg' );
  if i = 1 then
    bmpOut.Assign( bmpIn )
  else
    bmpOut.JoinBitmaps( nil, bmpIn, False, clWhite, True, 0.997 );
end;

// Show result
ImageEnView1.Assign( bmpOut );

bmpIn .Free;
bmpOut.Free;

---